БСП: Дополнительная обработка (Регламенты), примеры от простого к сложному

Публикация № 827126

Разработка - Практика программирования

РЗ Регламентное задание БСП Дополнительные обработки Отладка Обработка

241
Очень много попадается странных решений, которые можно решить через БСП:Дополнительные отчеты и обработки. Я бы вообще БСП из-за этой подсистемы переименовал в «Большое Спасибо Программистам». Поработаем с подсистемой в части написания регламентных заданий.

Если у Вас возник вопрос, как можно вообще напортачить с регламентными заданиями? Почитайте живые примеры из статьи -> Велостыли: Регламентные задания

Для экспериментов я использовал Платформы 8.3.10.2650 и 8.3.12.1412, конфигурации БСП 2.4.6.56 и 3.0.1.127.

Устанавливаем демо конфигурацию БСП и поехали! Работать будем со Справочником «Заметки». У него есть реквизит Содержание с типом ХранилищеЗначения, а это значит, туда много, что записать можно, ну и присутствуют другие реквизиты, с которыми тоже поработаем.

Содержание:

1 Один регламент

2 Регламент и форма с ручным запуском.

3 Два регламента, форма с ручным запуском и сохранение параметров для регламентов.

Рекомендации по отладке.

Задачи и решения.

Задача 1. Создать с помощью регламента новый элемент справочника Заметки и записать в реквизит содержание «Заметка создана регламентом в Время создания»

Создаем внешнюю обработку, назовем ее, например, «БСП_ДО_Регламенты»

Добавляем код в модуль:

// Возвращает сведения о внешней обработке.
Функция СведенияОВнешнейОбработке() Экспорт
	
	ПараметрыРегистрации = ДополнительныеОтчетыИОбработки.СведенияОВнешнейОбработке("2.4.5.71");
	
	ПараметрыРегистрации.Вид = ДополнительныеОтчетыИОбработкиКлиентСервер.ВидОбработкиДополнительнаяОбработка();
	ПараметрыРегистрации.Версия = "1.0.01";
	
	НоваяКоманда = ПараметрыРегистрации.Команды.Добавить();
	НоваяКоманда.Представление = НСтр("ru = 'Задача 1 регламент'");
	НоваяКоманда.Идентификатор = "Задача1Регламент";
	НоваяКоманда.Использование = ДополнительныеОтчетыИОбработкиКлиентСервер.ТипКомандыВызовСерверногоМетода();
	НоваяКоманда.ПоказыватьОповещение = Истина;
	
	Возврат ПараметрыРегистрации;
	
КонецФункции

// Интерфейс для запуска логики обработки.
Процедура ВыполнитьКоманду(ИмяКоманды, ПараметрыВыполнения) Экспорт
	
	// Диспетчеризация обработчиков команд.
	Если ИмяКоманды = "Задача1Регламент" Тогда
		Команда_ЗаДача1(ПараметрыВыполнения);
	КонецЕсли;
	
КонецПроцедуры

Процедура Команда_ЗаДача1(ПараметрыВыполнения)
	
	СоздатьНовыйЭлементСправочникаЗаметки(ПараметрыВыполнения);
		
КонецПроцедуры	

Процедура СоздатьНовыйЭлементСправочникаЗаметки(ПараметрыВыполнения)
	//Создаем новый элемент справочника
	ТекущийОбъект = Справочники.Заметки.СоздатьЭлемент();
	
	ДатаТекСеанса = ТекущаяДатаСеанса();
	
	//Формируем текст для Содержания
	ФорматированныйТекст = Новый ФорматированныйДокумент;
	ФорматированныйТекст.Добавить("Заметка создана регламентом в " + Строка(ДатаТекСеанса),Тип("ТекстФорматированногоДокумента"));
	
	ТекущийОбъект.Содержание = Новый ХранилищеЗначения(ФорматированныйТекст, Новый СжатиеДанных(9));
	
	ТекстHTML = "";
	Вложения = Новый Структура;
	ФорматированныйТекст.ПолучитьHTML(ТекстHTML, Вложения);
	
	ТекущийОбъект.ТекстСодержания	= СтроковыеФункцииКлиентСервер.ИзвлечьТекстИзHTML(ТекстHTML);
	
	ТекущийОбъект.ДатаИзменения 	= ДатаТекСеанса;
	ТекущийОбъект.Автор 			= ПараметрыСеанса.ТекущийПользователь;
	ТекущийОбъект.Пометка 			= Перечисления.ЦветаЗаметок.Красный;
	ТекущийОбъект.ДляРабочегоСтола	= Истина;
	
	ТекущийОбъект.Записать();
КонецПроцедуры

Сохраняем обработку и добавляем ее в нашу конфигурацию для тестов БСП демо.

Моя настройка: C 6 мая 2018 г. каждый день; по 23:59:59 каждые 60 секунд.

Записываем и проверяем.

Вот так просто можно добавить регламент, не изменяя типовой конфигурации. Когда-нибудь РЗ возможно можно будет добавлять через расширение, а пока можно использовать БСП.

Задача 2. В созданную нами дополнительную обработку необходимо добавить форму с возможностью ручного запуска регламентного задания. При этом в содержание надо писать создана заметка вручную или по регламенту.

Меняем код в модуле обработки:

// Возвращает сведения о внешней обработке.
Функция СведенияОВнешнейОбработке() Экспорт
	
	ПараметрыРегистрации = ДополнительныеОтчетыИОбработки.СведенияОВнешнейОбработке("2.4.5.71");
	//ПараметрыРегистрации.Вставить("БезопасныйРежим", Ложь);
	
	ПараметрыРегистрации.Вид = ДополнительныеОтчетыИОбработкиКлиентСервер.ВидОбработкиДополнительнаяОбработка();
	ПараметрыРегистрации.Версия = "1.0.02";
	
	//Открываем форму
	НоваяКоманда = ПараметрыРегистрации.Команды.Добавить();
	НоваяКоманда.Представление = НСтр("ru = 'Форма задач по регламентам'");
	НоваяКоманда.Идентификатор = "НастроитьИВыполнитьЗадачиВручную";
	НоваяКоманда.Использование = ДополнительныеОтчетыИОбработкиКлиентСервер.ТипКомандыОткрытиеФормы();
	НоваяКоманда.ПоказыватьОповещение = Ложь;
	
	//Регламент1
	НоваяКоманда = ПараметрыРегистрации.Команды.Добавить();
	НоваяКоманда.Представление = НСтр("ru = 'Задача 1 регламент'");
	НоваяКоманда.Идентификатор = "Задача1Регламент";
	НоваяКоманда.Использование = ДополнительныеОтчетыИОбработкиКлиентСервер.ТипКомандыВызовСерверногоМетода();
	НоваяКоманда.ПоказыватьОповещение = Истина;
	
	Возврат ПараметрыРегистрации;
	
КонецФункции

// Интерфейс для запуска логики обработки.
Процедура ВыполнитьКоманду(ИмяКоманды, ПараметрыВыполнения) Экспорт
	//Если в структуре параметров не передан вид запуска считаем что это запуск регламентом
	Если не ПараметрыВыполнения.свойство("ВидЗапускаРегламент") Тогда 
		ПараметрыВыполнения.Вставить("ВидЗапускаРегламент",Истина);	
	КонецЕсли;	
	
	// Диспетчеризация обработчиков команд.
	Если ИмяКоманды = "Задача1Регламент" Тогда
		Команда_ЗаДача1(ПараметрыВыполнения);
	КонецЕсли;
	
КонецПроцедуры

Процедура Команда_ЗаДача1(ПараметрыВыполнения)

	СоздатьНовыйЭлементСправочникаЗаметки(ПараметрыВыполнения);
		
КонецПроцедуры	

Процедура СоздатьНовыйЭлементСправочникаЗаметки(ПараметрыВыполнения)
	//Создаем новый элемент справочника
	ТекущийОбъект = Справочники.Заметки.СоздатьЭлемент();
	
	ДатаТекСеанса = ТекущаяДатаСеанса();
	
	//Формируем текст для Содержания
	ФорматированныйТекст = Новый ФорматированныйДокумент;
	
	//Добавили проверку регламент\форма
	ФорматированныйТекст.Добавить("Заметка создана " + ?(ПараметрыВыполнения.ВидЗапускаРегламент,"регламентом","вручную") + " в "+Строка(ДатаТекСеанса), Тип("ТекстФорматированногоДокумента"));
	
	ТекущийОбъект.Содержание = Новый ХранилищеЗначения(ФорматированныйТекст, Новый СжатиеДанных(9));
	
	ТекстHTML = "";
	Вложения = Новый Структура;
	ФорматированныйТекст.ПолучитьHTML(ТекстHTML, Вложения);
	
	ТекущийОбъект.ТекстСодержания	= СтроковыеФункцииКлиентСервер.ИзвлечьТекстИзHTML(ТекстHTML);
	
	ТекущийОбъект.ДатаИзменения 	= ДатаТекСеанса;
	ТекущийОбъект.Автор 			= ПараметрыСеанса.ТекущийПользователь;
	ТекущийОбъект.Пометка 			= Перечисления.ЦветаЗаметок.Красный;
	ТекущийОбъект.ДляРабочегоСтола	= Истина;
	
	ТекущийОбъект.Записать();
КонецПроцедуры	

Добавляем форму и создаем команду «Задание2»

&НаКлиенте
Процедура Задание2(Команда)
	Задание2НаСервере();
КонецПроцедуры

&НаСервере
Процедура Задание2НаСервере()
	ПараметрыВыполнения = новый Структура("ВидЗапускаРегламент",Ложь);
	ИмяКоманды = "Задача1Регламент";
	
	ОбрОбъект = РеквизитФормыВЗначение("Объект");
	ОбрОбъект.ВыполнитьКоманду(ИмяКоманды, ПараметрыВыполнения);
КонецПроцедуры

Записываем и заменяем предыдущую дополнительную обработку на эту.

Проверяем результат:

Задача 3. Создать второе регламентное задание и сделать  так, чтобы можно было сохранять параметры настроек, текст содержания и цвет (Пометка). При выполнении заданий параметры заполняют элемент справочника «Заметки». Ранее созданная кнопка должна запускать выбранное задание.

Редактируем функцию СведенияОВнешнейОбработке в модуле обработки. Добавляем второе регламентное задание.

// Возвращает сведения о внешней обработке.
Функция СведенияОВнешнейОбработке() Экспорт
	
	ПараметрыРегистрации = ДополнительныеОтчетыИОбработки.СведенияОВнешнейОбработке("2.4.5.71");
	
	ПараметрыРегистрации.Вид = ДополнительныеОтчетыИОбработкиКлиентСервер.ВидОбработкиДополнительнаяОбработка();
	ПараметрыРегистрации.Версия = "1.0.06";
	
	//Открываем форму
	НоваяКоманда = ПараметрыРегистрации.Команды.Добавить();
	НоваяКоманда.Представление = НСтр("ru = 'Форма задач по регламентам'");
	НоваяКоманда.Идентификатор = "НастроитьИВыполнитьЗадачиВручную";
	НоваяКоманда.Использование = ДополнительныеОтчетыИОбработкиКлиентСервер.ТипКомандыОткрытиеФормы();
	НоваяКоманда.ПоказыватьОповещение = Ложь;
	
	//Регламент1
	НоваяКоманда = ПараметрыРегистрации.Команды.Добавить();
	НоваяКоманда.Представление = НСтр("ru = 'Задача 1 регламент'");
	НоваяКоманда.Идентификатор = "Задача1Регламент";
	НоваяКоманда.Использование = ДополнительныеОтчетыИОбработкиКлиентСервер.ТипКомандыВызовСерверногоМетода();
	НоваяКоманда.ПоказыватьОповещение = Истина;
	
	//Регламент2
	НоваяКоманда = ПараметрыРегистрации.Команды.Добавить();
	НоваяКоманда.Представление = НСтр("ru = 'Задача 2 регламент'");
	НоваяКоманда.Идентификатор = "Задача2Регламент";
	НоваяКоманда.Использование = ДополнительныеОтчетыИОбработкиКлиентСервер.ТипКомандыВызовСерверногоМетода();
	НоваяКоманда.ПоказыватьОповещение = Истина;

	Возврат ПараметрыРегистрации;
	
КонецФункции

К модулю вернемся позже. Переходим к редактированию формы.

Создаем параметр формы "ДополнительнаяОбработкаСсылка" с типом "СправочникСсылка.ДополнительныеОтчетыИОбработки"

Создаем реквизиты формы.

"РегламентноеЗаданиеСписок" с типом "Строка"

"СписокРЗ" с типом "ТаблицаЗначений"

                -"КлючРЗ" с типом "Строка"

                -"ТекстСодержания" с типом "Строка"

                -"Пометка" с типом "ПеречислениеСсылка.ЦветаЗаметок"

Переименовываем команду «Задание2» в команду «ВыполнитьРЗ», соответственно процедуру тоже приводим к такому имени.

Создаем команду «ЗаписатьИзменения»

Форму делаем вот такого вида

Подготовительные работы выполнены, переходим к программированию.

Список для списка РЗ и ключи РЗ будем брать из модуля обработки, из функции СведенияОВнешнейОбработке она Экспортная. Нас интересуют все команды где Использование = ДополнительныеОтчетыИОбработкиКлиентСервер.ТипКомандыВызовСерверногоМетода();

Дальше мы будем считывать параметры, сохраненные в обработке Хранить их будем в ХранилищеНастроек

Для того чтобы делать меньше телодвижений в модуле обработки пропишем структуру для чистых настроек, для этого создадим экспортную функцию ПолучитьЧистуюСтруктуруНастроек

//Чистые настройки
Функция ПолучитьЧистуюСтруктуруНастроек() Экспорт
	СтруктураДанных = Новый Структура;
	СписокРЗ = Новый ТаблицаЗначений;
	СписокРЗ.Колонки.Добавить("КлючРЗ");
	СписокРЗ.Колонки.Добавить("ТекстСодержания");
	СписокРЗ.Колонки.Добавить("Пометка");
	
	СтруктураДанных.Вставить("СписокРЗ",СписокРЗ);
	Возврат СтруктураДанных;
КонецФункции

Создаем процедуру ПриСозданииНаСервере

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
	ЗаполнитьЗаписаннымиДанными();
КонецПроцедуры
Процедура ЗаполнитьЗаписаннымиДанными()
	ОбрОбъект = РеквизитФормыВЗначение("Объект");
	
	//Читаем информацию по доп обработке
	ПолучитьСведеньяОбработки = ОбрОбъект.СведенияОВнешнейОбработке();
	
	//В ТЗ Команды будем забирать только регламенты
	ПараметрыОтбора = Новый Структура;
	ПараметрыОтбора.Вставить("Использование", ДополнительныеОтчетыИОбработкиКлиентСервер.ТипКомандыВызовСерверногоМетода());
	СтрокиРЗ = ПолучитьСведеньяОбработки.Команды.НайтиСтроки(ПараметрыОтбора);
	
	ОбъектСсылка = Параметры.ДополнительнаяОбработкаСсылка;
	
	перСтруктураНормальная = Ложь;
	Если ЗначениеЗаполнено(ОбъектСсылка) Тогда	
		//Читаем ХранилищеНастроек
		перОбщиеПараметры = ОбщегоНазначения.ЗначениеРеквизитаОбъекта(ОбъектСсылка, "ХранилищеНастроек");
		СтруктураОбщиеПараметры = перОбщиеПараметры.Получить();
		
		Если Не ЗначениеЗаполнено(СтруктураОбщиеПараметры) Тогда 
			//записываем чистую структуру
			СтруктураОбщиеПараметры = ОбрОбъект.ПолучитьЧистуюСтруктуруНастроек(); 
		
		КонецЕсли;
		
		Если СтруктураОбщиеПараметры.Свойство("СписокРЗ") Тогда
			Если ТипЗнч(СтруктураОбщиеПараметры.СписокРЗ) = Тип("ТаблицаЗначений") Тогда 
				перСтруктураНормальная = Истина;	
	        КонецЕсли;
		КонецЕсли;
	КонецЕсли;
	
	МассивРЗ = Новый Массив;
	Если перСтруктураНормальная Тогда
		//Собираем данные для вывода на форму
		Для Каждого СтрокаРЗ Из СтрокиРЗ Цикл
			//Собираем Элементы.РегламентноеЗаданиеСписок.СписокВыбора
	        МассивРЗ.Добавить(СтрокаРЗ.Идентификатор);
			
			ПараметрыОтбора		= Новый Структура;
			ПараметрыОтбора.Вставить("КлючРЗ", СтрокаРЗ.Идентификатор);
			НайденныеСтрокиРЗ	= СтруктураОбщиеПараметры.СписокРЗ.НайтиСтроки(ПараметрыОтбора);	
			
			Если НайденныеСтрокиРЗ.Количество() = 0 Тогда 
				НовСтрока 			= СписокРЗ.Добавить();
	        	НовСтрока.КлючРЗ	= СтрокаРЗ.Идентификатор;	
			Иначе	
				Для Каждого нСтрокаРЗ из НайденныеСтрокиРЗ Цикл 
					НовСтрока = СписокРЗ.Добавить();
					ЗаполнитьЗначенияСвойств(НовСтрока,нСтрокаРЗ);
				КонецЦикла;	
			КонецЕсли;	
		КонецЦикла;	
	Иначе
		//Если настройки отсутствуют в сохраненных настройках, добавляем их в таблицу со значениями по умолчанию
		Для Каждого СтрокаРЗ Из СтрокиРЗ Цикл	
			//Собираем Элементы.РегламентноеЗаданиеСписок.СписокВыбора
			МассивРЗ.Добавить(СтрокаРЗ.Идентификатор);
			
			НовСтрока 					= СписокРЗ.Добавить();
	        НовСтрока.КлючРЗ			= СтрокаРЗ.Идентификатор;
	    КонецЦикла;	
	КонецЕсли;
	//Заполняем список заданий
	Элементы.РегламентноеЗаданиеСписок.СписокВыбора.ЗагрузитьЗначения(МассивРЗ);	
КонецПроцедуры

Создаем процедуру для команды «ЗаписатьИзменения»

&НаКлиенте
Процедура ЗаписатьИзменения(Команда)
	ЗаписатьИзмененияНаСервере();
КонецПроцедуры
&НаСервере
Процедура ЗаписатьИзмененияНаСервере()
	Если не ЗначениеЗаполнено(Параметры.ДополнительнаяОбработкаСсылка) Тогда 
		Сообщить("Запись работает только в режиме встроенной доп обработки!",СтатусСообщения.Важное);
		Возврат;	
	КонецЕсли;	
	
	СтруктураДанных = Новый Структура("СписокРЗ",СписокРЗ.Выгрузить());
	
	ДополнительнаяОбработкаОбъект = Параметры.ДополнительнаяОбработкаСсылка.ПолучитьОбъект();
	ДополнительнаяОбработкаОбъект.ХранилищеНастроек = Новый ХранилищеЗначения(СтруктураДанных);
	ДополнительнаяОбработкаОбъект.Записать();
КонецПроцедуры

Изменяем процедуру для команды «ВыполнитьРЗ»

&НаКлиенте
Процедура ВыполнитьРЗ(Команда)
	ВыполнитьРЗНаСервере();
КонецПроцедуры

&НаСервере
Процедура ВыполнитьРЗНаСервере()
	Если не ЗначениеЗаполнено(РегламентноеЗаданиеСписок) Тогда 
		Сообщить("Выберите РЗ!!!",СтатусСообщения.Важное);
		Возврат;
	КонецЕсли;	
	
	ПараметрыОтбора		= Новый Структура;
	ПараметрыОтбора.Вставить("КлючРЗ", РегламентноеЗаданиеСписок);
	НайденныеСтрокиРЗ	= СписокРЗ.НайтиСтроки(ПараметрыОтбора);	
			
	Если НайденныеСтрокиРЗ.Количество() = 0 Тогда
		Сообщить("Не найдено параметров РЗ!!! "+РегламентноеЗаданиеСписок,СтатусСообщения.Важное);
		Возврат;
	КонецЕсли;	
	
	//ПараметрыРЗ формируем на клиенте, вдруг не записали в ТЗ изменения
	ПараметрыВыполнения = новый Структура("ПараметрыРЗ");
	ПараметрыВыполнения.Вставить("ВидЗапускаРегламент",Ложь);
	ИмяКоманды = РегламентноеЗаданиеСписок;
	
	ОбрОбъект = РеквизитФормыВЗначение("Объект");
	//Если вдруг умудрились задублировать в ТЗ регламенты
	Для Каждого СтрокаРЗ из НайденныеСтрокиРЗ Цикл 
	    ПараметрыВыполнения.ПараметрыРЗ = Новый Структура("ТекстСодержания,Пометка",
										СтрокаРЗ.ТекстСодержания,
										СтрокаРЗ.Пометка);
		ОбрОбъект.ВыполнитьКоманду(ИмяКоманды, ПараметрыВыполнения);	
	КонецЦикла;	
КонецПроцедуры

Изменяем в модуле обработки процедуру «ВыполнитьКоманду»

// Интерфейс для запуска логики обработки.
Процедура ВыполнитьКоманду(ИмяКоманды, ПараметрыВыполнения) Экспорт
	//Если в структуре параметров не передан вид запуска считаем что это запуск регламентом
	Если не ПараметрыВыполнения.свойство("ВидЗапускаРегламент") Тогда 
		ПараметрыВыполнения.Вставить("ВидЗапускаРегламент",Истина);	
	КонецЕсли;	
	
	// Диспетчеризация обработчиков команд.
	Если ИмяКоманды = "Задача1Регламент" 
		или ИмяКоманды = "Задача2Регламент" Тогда
		
		Если ПараметрыВыполнения.ВидЗапускаРегламент Тогда 
			ОбъектСсылка = ПараметрыВыполнения.ДополнительнаяОбработкаСсылка;	
			Если ЗначениеЗаполнено(ОбъектСсылка) Тогда	
				//Читаем ХранилищеНастроек
				перОбщиеПараметры = ОбщегоНазначения.ЗначениеРеквизитаОбъекта(ОбъектСсылка, "ХранилищеНастроек");
				СтруктураОбщиеПараметры = перОбщиеПараметры.Получить();
				
				Если Не ЗначениеЗаполнено(СтруктураОбщиеПараметры) Тогда 
					//записываем чистую структуру
					СтруктураОбщиеПараметры = ПолучитьЧистуюСтруктуруНастроек(); 
				
				КонецЕсли;
				
				Если СтруктураОбщиеПараметры.Свойство("СписокРЗ") Тогда
					Если ТипЗнч(СтруктураОбщиеПараметры.СписокРЗ) = Тип("ТаблицаЗначений") Тогда 
						
						//Все проверки прошли
						ПараметрыОтбора		= Новый Структура;
						ПараметрыОтбора.Вставить("КлючРЗ", ИмяКоманды);
						НайденныеСтрокиРЗ	= СтруктураОбщиеПараметры.СписокРЗ.НайтиСтроки(ПараметрыОтбора);
						
						Если НайденныеСтрокиРЗ.Количество() > 0 Тогда

							//Если вдруг умудрились задублировать в ТЗ регламенты
							Для Каждого СтрокаРЗ из НайденныеСтрокиРЗ Цикл 
								
								Если ПараметрыВыполнения.Свойство("ПараметрыРЗ") Тогда 
								
							    	ПараметрыВыполнения.ПараметрыРЗ = Новый Структура("ТекстСодержания,Пометка",
																СтрокаРЗ.ТекстСодержания,
																СтрокаРЗ.Пометка);
								Иначе
									ПараметрыВыполнения.Вставить("ПараметрыРЗ",Новый Структура("ТекстСодержания,Пометка",
																СтрокаРЗ.ТекстСодержания,
																СтрокаРЗ.Пометка));							
								КонецЕсли;
								
								Команда_ЗаДача1(ПараметрыВыполнения);
							
							КонецЦикла;	
						КонецЕсли;
						
			        КонецЕсли;
				КонецЕсли;
			КонецЕсли;
		Иначе	
			Команда_ЗаДача1(ПараметрыВыполнения);
		КонецЕсли;
	КонецЕсли;
	
КонецПроцедуры

и процедуру «СоздатьНовыйЭлементСправочникаЗаметки»

Процедура Команда_ЗаДача1(ПараметрыВыполнения)
     
	СоздатьНовыйЭлементСправочникаЗаметки(ПараметрыВыполнения);
		
КонецПроцедуры	

Процедура СоздатьНовыйЭлементСправочникаЗаметки(ПараметрыВыполнения)
	//Создаем новый элемент справочника
	ТекущийОбъект = Справочники.Заметки.СоздатьЭлемент();
	
	ДатаТекСеанса = ТекущаяДатаСеанса();
	
	//Формируем текст для Содержания
	ФорматированныйТекст = Новый ФорматированныйДокумент;
	
	//Обрабатываем Параметры
	перТекстСодержания = "Заметка создана ";
	перПометка = Перечисления.ЦветаЗаметок.Красный;
	Если ПараметрыВыполнения.Свойство("ПараметрыРЗ") Тогда 
		Если ТипЗнч(ПараметрыВыполнения.ПараметрыРЗ) = Тип("Структура") Тогда 
			Если ПараметрыВыполнения.ПараметрыРЗ.Свойство("ТекстСодержания") Тогда 
				Если ЗначениеЗаполнено(ПараметрыВыполнения.ПараметрыРЗ.ТекстСодержания) Тогда 
					перТекстСодержания = ПараметрыВыполнения.ПараметрыРЗ.ТекстСодержания;	
				КонецЕсли;	
			КонецЕсли;
			
			Если ПараметрыВыполнения.ПараметрыРЗ.Свойство("Пометка") Тогда 
				Если ЗначениеЗаполнено(ПараметрыВыполнения.ПараметрыРЗ.Пометка) Тогда 
					перПометка = ПараметрыВыполнения.ПараметрыРЗ.Пометка;	
				КонецЕсли;	
			КонецЕсли;

		КонецЕсли;	
	КонецЕсли;

	//Добавили проверку регламент\форма		
	ФорматированныйТекст.Добавить(перТекстСодержания + ?(ПараметрыВыполнения.ВидЗапускаРегламент,"регламентом","вручную") + " в "+Строка(ДатаТекСеанса), Тип("ТекстФорматированногоДокумента"));
	
	ТекущийОбъект.Содержание = Новый ХранилищеЗначения(ФорматированныйТекст, Новый СжатиеДанных(9));
	
	ТекстHTML = "";
	Вложения = Новый Структура;
	ФорматированныйТекст.ПолучитьHTML(ТекстHTML, Вложения);
	
	ТекущийОбъект.ТекстСодержания	= СтроковыеФункцииКлиентСервер.ИзвлечьТекстИзHTML(ТекстHTML);
	
	ТекущийОбъект.ДатаИзменения 	= ДатаТекСеанса;
	ТекущийОбъект.Автор 			= ПараметрыСеанса.ТекущийПользователь;

	ТекущийОбъект.Пометка 			= перПометка;
	ТекущийОбъект.ДляРабочегоСтола	= Истина;
	
	ТекущийОбъект.Записать();
КонецПроцедуры

Записываем и заменяем предыдущую дополнительную обработку на эту.

Заполняем настройки.

Проверяем ручной запуск и регламеты

Проверяем результат:

В коде можно было бы проверки вынести в одну процедуру\функцию. Как вы видите просто безграничные возможности предоставлены программистам по разработке сложных регламентов без доработки конфигурации.

Отладка.

Отладку регламентов можно проводить по описанию из этой статьи Отладка подключаемых обработок

Корректную отладку запуска из формы можно производить после того как в Параметры.ДополнительнаяОбработкаСсылка будет закинута ссылка на добавленную дополнительную обработкую. В нашем случае, достаточно просто в процедуру формы "ПриСозданииНаСервере" добавить одну строчку.

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
	//Для тестирования ХранилищеНастроек
	Параметры.ДополнительнаяОбработкаСсылка = Справочники.ДополнительныеОтчетыИОбработки.НайтиПоРеквизиту("ИмяОбъекта","БСП_ДО_Регламенты");
	ЗаполнитьЗаписаннымиДанными();
КонецПроцедуры

 

П.С. Пока писал данную статью в голову пришла еще одна по данной тематике.  БСП: Дополнительная обработка (Регламенты) + Расширения, примеры от сложного к универсальному

UPD 27.07.2019. Добавил файлы (Одна обработка несколько форм Файлы.rar) к статье БСП: Дополнительные отчеты и обработки - одна обработка несколько форм

Данная статья ответ на вопрос: Можно ли сделать так, чтобы у обработки было регл задание и две формы - работающие по-разному?

241

Скачать файлы

Наименование Файл Версия Размер
Дополнительная обработка (Регламенты) финальная
.epf 11,30Kb
09.05.18
26
.epf 1.0.8 11,30Kb 26 Скачать
БСП: Дополнительные отчеты и обработки - одна обработка несколько форм
.rar 35,62Kb
27.07.19
2
.rar 1 35,62Kb 2 Скачать

Специальные предложения

Лучшие комментарии
18. dsdred 1276 15.10.18 11:33 Сейчас в теме
(16)
Задача: из формы элемента ДополнительныеОтчетыИОбработки (или по-другому) открыть форму внешней обработки, один раз выбрать параметры, сохранить в ХранилищеНастроек, чтобы потом регл. задание считывало их оттуда. Как это лучше сделать для БСП 2.3.2.51?

Не нашел БСП 2.3.2.51 поэтому протестировал на 2.3.2.195

-добавляем обработку в доп очеты и обработки
-копию обработки открываем в конфигураторе

В обработке приложенной в данной статье раскоментируем код в модуле формы

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
//Для тестирования ХранилищеНастроек
Параметры.ДополнительнаяОбработкаСсылка = Справочники.ДополнительныеОтчетыИОбработки.НайтиПоРеквизиту("ИмяОбъекта","БСП_ДО_Регламенты");
ЗаполнитьЗаписаннымиДанными();
КонецПроцедуры

Открываем в клиенте и сохраняем параметры для рег. задания.
aleksey_korol; +1 Ответить
21. dsdred 1276 17.10.18 11:53 Сейчас в теме
(19)Прикладываю обработку.

скопировал в нее форму элемента справочника ДополнительныеОтчетыИОбработки из БСП 2.3.2.195

и создал простую форму с выбором ссылки из справочника ДополнительныеОтчетыИОбработки и команду открыть форму
Код команды: ОткрытьФорму("ВнешняяОбработка.ВнешняяОбработка1.Форма.ФормаЭлемента",новый Структура("Ключ",ДопОбработкаСсылка),ЭтаФорма);

Прин скрины прикладываю.
Прикрепленные файлы:
ВнешняяОбработка1.epf
aleksey_korol; +1 Ответить
Остальные комментарии
Избранное Подписка Сортировка: Древо
1. Dream_kz 95 10.05.18 08:17 Сейчас в теме
Как раз нужны были примеры по запуску доп. обработок по времени + хранение настроек этих самых обработок. Спасибо
2. dsdred 1276 10.05.18 08:21 Сейчас в теме
(1)
Как раз нужны были примеры по запуску доп. обработок по времени + хранение настроек этих самых обработок. Спасибо

Отлично, значит не зря писал статью.
3. rafaiil 10.05.18 08:51 Сейчас в теме
Отлично! Большое спасибо!;) Очень полезный для меня материал.
rutony; dsdred; +2 Ответить
4. TrinitronOTV 10.05.18 09:16 Сейчас в теме
Спасибо, пригодится
rutony; dsdred; +2 Ответить
5. jONES1979 10.05.18 09:18 Сейчас в теме
Эта статья интересна! Напишите еще одну, более интересную! :)
EGOLEGE; Max27; rutony; dsdred; +4 Ответить
6. dsdred 1276 10.05.18 09:23 Сейчас в теме
(5)
Эта статья интересна! Напишите еще одну, более интересную! :)

Ну судя по тому, что статья быстро набирает положительные голоса. Скорее всего будет продолжение.
7. Ava1or 10.05.18 16:40 Сейчас в теме
Спасибо! Огонь статья!
Эх, написал бы ты ее месяцок назад... Но уже сам разобрался)
8. dsdred 1276 10.05.18 21:30 Сейчас в теме
(7)Знал бы, что будет так интересна читателям, написал бы раньше))
9. serega_new 11.05.18 11:51 Сейчас в теме
Вот интересно почему в БСП четко не прописали в описании как хранить настройки для регламентных обработок, в демо БСП есть пример с хранением, но такой же не очевидный как и у вас. В голову не ложится, вот кстати уже шаблон делали - https://infostart.ru/public/627824/
10. dsdred 1276 11.05.18 12:01 Сейчас в теме
(9)Спасибо, не видел данную статью.
На счет описания 1с. Не знаю почему они пишут поверхностное описание. По сути желтые книжки могут служить только как справочник о том, что можно сделать и удобной подпоркой дивана если отпала ножка... А то как сделать google в помощь. Если не нашел сиди сам пробуй...

Да, в БСП есть пример (если кому понадобится)-> Демо: Загрузка номенклатуры из прайс-листа (профили безопасности)
Код сохранения настроек из обработки:

&НаСервереБезКонтекста
Процедура СохранитьНастройкиФормы(ДополнительнаяОбработкаСсылка, АдресФайла)
СохраняемоеЗначение = Новый Структура("АдресФайла", АдресФайла);

ДополнительнаяОбработкаОбъект = ДополнительнаяОбработкаСсылка.ПолучитьОбъект();
ДополнительнаяОбработкаОбъект.ХранилищеНастроек = Новый ХранилищеЗначения(СохраняемоеЗначение);
ДополнительнаяОбработкаОбъект.Записать();
КонецПроцедуры

чтение ПриСозданииНаСервере
11. Danilov 21.05.18 04:48 Сейчас в теме
Отличная статья. Возьму на заметку.
12. dsdred 1276 21.05.18 07:26 Сейчас в теме
(11) На этой неделе будет продолжение. Вторая часть на 90% готова.
13. aleksey_korol 11.10.18 18:25 Сейчас в теме
Как долго я искал, как передать параметры в регламент!
14. dsdred 1276 11.10.18 18:36 Сейчас в теме
(13)Рад, что статья пригодилась
15. aleksey_korol 13.10.18 18:26 Сейчас в теме
В БСП 2.3.2.51 нет кнопки "Выполнить" на странице "Команды" в форме элемента. Как вручную выполнить команду "Форма задач по регламентам"?
16. aleksey_korol 13.10.18 18:37 Сейчас в теме
(15) Задача: из формы элемента ДополнительныеОтчетыИОбработки (или по-другому) открыть форму внешней обработки, один раз выбрать параметры, сохранить в ХранилищеНастроек, чтобы потом регл. задание считывало их оттуда. Как это лучше сделать для БСП 2.3.2.51?
18. dsdred 1276 15.10.18 11:33 Сейчас в теме
(16)
Задача: из формы элемента ДополнительныеОтчетыИОбработки (или по-другому) открыть форму внешней обработки, один раз выбрать параметры, сохранить в ХранилищеНастроек, чтобы потом регл. задание считывало их оттуда. Как это лучше сделать для БСП 2.3.2.51?

Не нашел БСП 2.3.2.51 поэтому протестировал на 2.3.2.195

-добавляем обработку в доп очеты и обработки
-копию обработки открываем в конфигураторе

В обработке приложенной в данной статье раскоментируем код в модуле формы

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
//Для тестирования ХранилищеНастроек
Параметры.ДополнительнаяОбработкаСсылка = Справочники.ДополнительныеОтчетыИОбработки.НайтиПоРеквизиту("ИмяОбъекта","БСП_ДО_Регламенты");
ЗаполнитьЗаписаннымиДанными();
КонецПроцедуры

Открываем в клиенте и сохраняем параметры для рег. задания.
aleksey_korol; +1 Ответить
17. dsdred 1276 15.10.18 10:26 Сейчас в теме
(15)Первый вариант у меня описан в конце статьи в описании как отлаживать.

Корректную отладку запуска из формы можно производить после того как в Параметры.ДополнительнаяОбработкаСсылка будет закинута ссылка на добавленную дополнительную обработкую. В нашем случае, достаточно просто в процедуру формы "ПриСозданииНаСервере" добавить одну строчку.

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
//Для тестирования ХранилищеНастроек
Параметры.ДополнительнаяОбработкаСсылка = Справочники.ДополнительныеОтчетыИОбработки.НайтиПоРеквизиту("ИмяОбъекта","БСП_ДО_Регламенты");
ЗаполнитьЗаписаннымиДанными();
КонецПроцедуры



Второй вариант сейчас протестирую и отпишусь.
aleksey_korol; +1 Ответить
19. aleksey_korol 17.10.18 09:54 Сейчас в теме
(17) Хотя бы вкратце: на чем основан 2-й вариант?
20. dsdred 1276 17.10.18 11:18 Сейчас в теме
(19)Вкраце просто создание команды по открытию формы через

ДополнительныеОтчетыИОбработкиКлиент.ВыполнитьОткрытиеФормыОбработки

ну или посмотреть какие в том модули еще варианты есть.
aleksey_korol; +1 Ответить
21. dsdred 1276 17.10.18 11:53 Сейчас в теме
(19)Прикладываю обработку.

скопировал в нее форму элемента справочника ДополнительныеОтчетыИОбработки из БСП 2.3.2.195

и создал простую форму с выбором ссылки из справочника ДополнительныеОтчетыИОбработки и команду открыть форму
Код команды: ОткрытьФорму("ВнешняяОбработка.ВнешняяОбработка1.Форма.ФормаЭлемента",новый Структура("Ключ",ДопОбработкаСсылка),ЭтаФорма);

Прин скрины прикладываю.
Прикрепленные файлы:
ВнешняяОбработка1.epf
aleksey_korol; +1 Ответить
22. sparhh 21.06.19 15:27 Сейчас в теме
А если создавать регламентное задание не через внешнюю обработку, а через встроенный объект.
То получается и теряется возможность гибко настраивать параметры регл. задания?
23. dsdred 1276 21.06.19 15:37 Сейчас в теме
(22)Да, потеряете возможность хранить параметры и придется либо создавать константу с типом Хранилище значений, но это неудобно если регламентов будет несколько. Либо создать справочник с реквизитом хранилище значений. И еще не забывайте про форму которая должна быть создана для работы с данными.

В этом и удобство данной подсистемы. У вас все в одном месте: параметры, форма и регламент.
24. sparhh 21.06.19 16:14 Сейчас в теме
(23) С одной стороны да, с другой же стороны. У тебя начинает копиться логика программы с кодом во внешних файлах.
25. sparhh 21.06.19 17:04 Сейчас в теме
(23) Я вот что не понимаю.. все таки.. если хочу сделать Регламентное задание через расширение, то в таком случае теряется легкость и гибкость, которая есть в механизме БСП Доп. обработки.
Так?
Я видел вашу статью на эту тему, но похоже на самописность..

К примеру есть механизм БСП "Заполнение объекта" и в расширениях он умеет преобразовываться уже в другой механизм.
В для регламентных заданиях нет такого, как я понял.
26. dsdred 1276 21.06.19 21:54 Сейчас в теме
(25)Не понимаю в чем вопрос?
27. user_2010 442 25.07.19 17:30 Сейчас в теме
можно ли сделать так, чтобы у обработки было регл задание и две формы - работающие по-разному?
28. dsdred 1276 26.07.19 18:28 Сейчас в теме
(27)
можно ли сделать так, чтобы у обработки было регл задание и две формы - работающие по-разному?

Огромное спасибо за вопрос, вы мне прям час работы скрасили!
Я дам подробный ответ в статье БСП: Дополнительные отчеты и обработки - одна обработка несколько форм опубликую ее в понедельник-вторник.

Огромная просьба описать ситуацию для которой Вам понадобилось несколько форм. Заранее спасибо!
29. user_2010 442 26.07.19 21:08 Сейчас в теме
(28) Большое спасибо!
Ваша статья мне очень помогла.
Вопрос возник при реализации задачи по загрузке данных из сторонних источников. Процедуры по чтению данных и загрузке - одни и те же. Но вот работать они могут по-разному:
1. Как регламентное задание - без участия пользователя.
2. Как обработка, запущенная пользователем, но без параметров - только одна кнопка "Загрузить", все параметры устанавливаются по умолчанию.
3. Как полноценная обработка пользователя с возможность указания своих параметров для чтения данных и настройки параметров для дальнейшей загрузки данных - при необходимости, и прочей дальнейшей обработки загруженных данных ....
Не хочется для этих целей плодить несколько обработок - хочется одну.
30. dsdred 1276 29.07.19 09:01 Сейчас в теме
31. user_2010 442 29.07.19 09:56 Сейчас в теме
32. Светлый ум 235 30.07.19 09:25 Сейчас в теме
Возьмем на вооружение, +1
33. Vyacheslide 5 14.08.19 11:18 Сейчас в теме
Огромное спасибо автору, искал как делать фоновые задания как то раз, ничего путного не нашел. Это же статья прямо разжевала и в рот положила. Респект!!!
34. dsdred 1276 14.08.19 11:22 Сейчас в теме
(33)Рад, что пригодилась статья.
Vyacheslide; +1 Ответить
Оставьте свое сообщение

См. также

Хороший заказчик - плохой заказчик 33

Статья no Нет файла Россия Бесплатно (free) О жизни

Лайфхак о том, как стать легендарным клиентом.

13.09.2019    4570    dsdred    24       

Cashback 35% при покупке 1С лицензий на счет INFOSTART.RU с 27.11 по 04.12 Промо

Оформляете заказ на 1С лицензии или конфигурации. Получаете 35% от стоимости на счет в профиле INFOSTART.RU. Выбираете сервисы и продукты на сумму кэшбэка.

Описание формата внутреннего представления данных 1С в контексте обмена данными 153

Статья Программист Внешняя обработка (ert,epf) v8 v8::УФ 1cv8.cf Абонемент ($m) Практика программирования Внешние источники данных Разработка

Фирма 1С не рекомендует использовать внутреннее представление данных для любых целей, которые отличны от обмена с 1С:Предприятием 7.7. Но сама возможность заглянуть на "внутреннюю кухню" платформы с помощью функций ЗначениеВСтрокуВнутр(), ЗначениеВФайл(), ЗначениеИзСтрокиВнутр() и ЗначениеИзФайла(), дала возможность сообществу программистов 1С разработать новые приемы разработки и анализа. Так, именно на использовании внутреннего представления был построен алгоритм "быстрого массива", который позволяет практически мгновенно создать массив в памяти на основании строки с разделителями. С помощью разбора внутреннего представления можно "на лету" программным кодом выполнить анализ обычной формы и даже сделать редактор графической схемы. Во внутреннем формате сохраняют свои данные между сеансами различные популярные внешние обработки. А еще это возможность сделать быстрый обмен с внешними системами.

1 стартмани

06.09.2019    6443    6    Dementor    27       

Онлайн-интенсив "Бизнес-процессы для подготовки к экзамену 1С:Специалист по платформе" 12 декабря 2019 г. Промо

На интенсиве будут рассмотрены все теоретические вопросы, связанные с устройством механизма бизнес-процессов – это необходимо для успешной сдачи экзамена 1С:Специалист по платформе. Также, в качестве практического примера, будет решена задача, аналогичная экзаменационной.

777 рублей

Вам нравятся запросы в 1С? 14

Инструменты и обработки Программист Конфигурация (md, cf) v8 v8::Запросы 1cv8.cf Абонемент ($m) Практика программирования Разработка

Речь не только о том, что простейший запрос с "легальным" оформлением растянется на пол-экрана, речь еще обо всем, что нужно написать "в нагрузку" к тексту запроса. Все эти "Новый Запрос", "УстановитьПараметр" и последующие пляски с обработкой результата... Пора с этим заканчивать!

1 стартмани

03.07.2019    11178    1    m-rv    79       

Перенос данных УТ 10.3 => УТ 11 / КА 2 / ERP 2 (ЕРП 2) (документы, остатки и справочная информация из "1С:Управление торговлей, ред. 10.3" в УТ 11 / КА 2 / ERP 2). Обновлен до УТ 10.3.56.х, УТ 11.4.10.х, КА 2.4.10.х и ERP 2.4.10.х! Промо

Уже более 100 компаний приобрели перенос и выполнили переход на УТ 11 / КА 2 / ERP 2 с помощью нашей разработки! Обработка перехода с УТ 10.3 на УТ 11 / КА 2 / ERP 2 позволяет перенести не только остатки на указанную дату (как типовой перенос), но и все возможные документы за выбранный период. При выходе новых релизов этих программ оперативно выпускаем обновление обработки. Предоставляем техническую поддержку. Можем сделать бесплатный тестовый перенос!

29700 руб.

1С:Ассемблер. Немного летнего веселья! 312

Статья Программист Внешняя обработка (ert,epf) v8 1cv8.cf Абонемент ($m) Практика программирования Разработка

Все вы, наверное, слышали, что 1С-ники жалуются на свою систему, считая язык 1С недостаточно низкоуровневым, скучным и т.п. Все они с тоской поглядывают в сторону "настоящих" языков программирования. Так вот, господа, они неправы. В системе 1С есть места, где можно размять программерский мозг и получить удовольствие от низкоуровневой техники. Предлагаю вам погрузиться в недра виртуальной машины 1С и понять, как она работает. Там есть свой "ассемблер" и мы попробуем его в действии!

1 стартмани

21.06.2019    15712    48    Evil Beaver    116       

Простые примеры сложных отчетов на СКД 269

Статья Программист Архив с данными v8 v8::СКД 1cv8.cf Абонемент ($m) Практика программирования

Подписи в отчете. Особенности соединения наборов: как соединить несоединяемое. Остатки на дату и обороты по месяцам в одном отчете. Курс валюты на каждую дату без группировок и соединений в запросе. Отчет с произвольными колонками и с произвольной последовательностью. "Неадекватный отчет".

1 стартмани

12.06.2019    15296    11    Hatson    22       

Перенос данных КА 1.1 / УПП 1.3 => БП 3.0 (перенос остатков, документов и справочников из "1С:Комплексная автоматизация 1.1" / УПП 1.3 в "1С:Бухгалтерия 3.0"). Обновлен до версий КА 1.1.115.х, УПП 1.3.127.х! Промо

Разработка позволяет перенести остатки по всем счетам бух.учета в программу "1С:Бухгалтерия предприятия 8", ред. 3.0 на выбранную дату начала ведения учета. Также переносятся документы за период и вся необходимая справочная информация. Правила оперативно обновляю при выходе новых релизов. Рассылка обновлений правил бесплатно в течение 12 месяцев. Есть видеодемонстрация проведения переноса данных. Конфигурации при использовании обмена остаются полностью типовыми. Перенос данных возможен в Бухгалтерию 3.0 версии ПРОФ, КОРП или базовую.

24700 руб.

Безопасная работа с транзакциями во встроенном языке 189

Статья Программист Конфигурация (md, cf) v8 1cv8.cf Абонемент ($m) Практика программирования

Разбираемся с опасностями использования транзакций во встроенном языке 1С. Познаем ошибку "В данной транзакции уже происходили ошибки". Учимся защищаться от них.

1 стартмани

25.03.2019    17069    8    tormozit    44       

Баг или фича? Неожиданное поведение платформы 170

Статья Системный администратор Программист Конфигурация (md, cf) v8 1cv8.cf Абонемент ($m) Практика программирования Тестирование и исправление Разработка

Рассмотрим несколько случаев неожиданного поведения платформы 1С, а также что с этим можно cделать.

18.02.2019    13595    31    YPermitin    88       

1СПАРК РИСКИ. Сервис оценки благонадежности контрагентов. Промо

СПАРК помогает предотвратить мошенничество со стороны компаний и предпринимателей, благодаря актуальным сведениям о компаниях и системе выявления факторов риска.Сервис позволяет управлять налоговыми рисками и комплексно оценивать благонадежность контрагентов.

Коннектор: удобный HTTP-клиент для 1С:Предприятие 8 559

Инструменты и обработки Программист Конфигурация (md, cf) v8 1cv8.cf Абонемент ($m) Практика программирования Внешние источники данных WEB Универсальные функции Инструментарий разработчика Универсальные обработки

Коннектор - библиотека для работы с HTTP запросами. Библиотека берет на себя всю рутину работы с HTTP запросами. Буквально в одну строку можно получать данные, отправлять, не заботясь о необходимости конструирования URL, кодирования данных и т.п.

1 стартмани

31.01.2019    30624    273    bonv    116       

HTML в новой версии 8.3.14 на примере 3-х JavaScript библиотек: AmCharts, HighCharts, DHTMLX 172

Статья Программист Внешняя обработка (ert,epf) v8 1cv8.cf Абонемент ($m) Универсальные обработки Практика программирования Разработка

Тестируем возможности HTML в новой версии 8.3.14 платформы на примере 3-х JavaScript библиотек: AmCharts, HighCharts, DHTMLX.

1 стартмани

29.01.2019    15523    66    Synoecium    37       

Перенос данных БП 2.0 => УТ 11 / КА 2 / ERP 2 (перенос остатков, документов и справочников из "1С:Бухгалтерия предприятия 8", ред. 2.0 в "1С:Управление торговлей 8", ред.11 / КА 2 / ERP 2). Обновлено до УТ 11.4.10.х, КА 2.4.10.х, ERP 2.4.10.х! Промо

Перенос позволяет загрузить в УТ 11 / КА 2 / ERP 2 документы за выбранный период, справочную информацию и остатки по счетам бух. учета. Переносятся остатки денежных средств, взаиморасчетов, остатки товаров и материалов на складах. Переносятся девятнадцать основных видов документов за выбранный период и вся нормативно-справочная информация. Есть фильтр по организации. Если нужно переносить что-то дополнительно, то обычно бесплатно дорабатываю правила (перед покупкой согласуйте необходимые доработки).

29700 руб.

Чтобы не стыдно было... 34

Статья no Нет файла Бесплатно (free) О жизни

Как и где работать так, чтобы "было не стыдно"?

29.10.2018    6960    dsdred    107       

HTTP Сервисы: Путь к своему сервису. Часть 4 107

Статья Системный администратор Программист Расширение (cfe) v8 1cv8.cf Абонемент ($m) Инструментарий разработчика Практика программирования

Продолжение статьи «HTTP Сервисы: Путь к своему сервису. Часть 3». В предыдущих частях мы уже о многом поговорили. В этой части поговорим про размер сообщений, о файлах, о порциях и немножко, о регламентах.

1 стартмани

28.09.2018    14422    17    dsdred    12       

Программы для исполнения 488-ФЗ: Маркировка товаров Промо

1 января 2019 года вступил в силу ФЗ от 25.12.2018 № 488-ФЗ о единой информационной системе маркировки товаров с использованием контрольных (идентификационных) знаков, который позволяет проследить движение товара от производителя до конечного потребителя. Инфостарт предлагает подборку программ, связанных с применением 488-ФЗ и маркировкой товаров.

Работа с публикациями "Инфостарт" 14

Инструменты и обработки Программист Архив с данными v8 УУ Абонемент ($m) Практика программирования О сообществе WEB

Работа с рублевыми публикациями на сайте "Инфостарт": ведение клиентов, заказов, обновление файлов публикации, рассылка обновлений.

1 стартмани

13.09.2018    10510    10    RocKeR_13    16       

Позиционирование в помещении с помощью нейросети по сигналу Wi-Fi. Интерактивная карта склада в 1С с показом позиции 65

Инструменты и обработки Программист Бизнес-аналитик Приложение (apk) v8 Windows Абонемент ($m) Инструментарий разработчика Практика программирования

Данная публикация содержит в себе редактор и интерактивную карту склада или иного помещения, на которой в реальном времени отображается позиция устройства, координаты которого вычисляются по уровням сигнала нескольких роутеров Wi-Fi. В статье и приложенным к ней разработкам предлагаются инструменты и методика для реализации вычисления точной геопозиции внутри помещений с помощью нейронной сети. Конфигурация написана на релизе 1С:Предприятие 8.3.12.1412, клиентское приложение имеет минимальный уровень совместимости SDK -16.

5 стартмани

09.08.2018    16976    23    informa1555    26       

1С:Предприятие через Интернет. 1С:Fresh Промо

Ведение бухгалтерского и налогового учет, сдача отчетности, управление бизнесом из любой точки мира. Привычные программы «1С» через Интернет без приобретения коробочных программ.

Работа с данными выбора 40

Инструменты и обработки Программист Архив с данными v8 Россия Абонемент ($m) Практика программирования Работа с интерфейсом

В управляемом интерфейсе заложена мощная возможность описывать связи реквизитов формы через параметры. Установка параметров связей позволяет ограничить выбор данных так, чтобы целостность данных была обеспечена на этапе ввода. Однако без дополнительного программирования задать можно только самые простые связи. Такие условия связи, как зависимость от реквизита через точку или зависимость через дополнительное отношение, заданное в регистре сведений - уже задать без программирования не получится.

1 стартмани

17.07.2018    23782    13    kalyaka    15       

HTTP Сервисы: Путь к своему сервису. Часть 1 287

Статья Системный администратор Программист Расширение (cfe) v8 1cv8.cf Абонемент ($m) Практика программирования WEB

Уже много было написано про http-сервисы, но то и дело всплывают «Новые» статьи по обмену между базами V8 по COM, что «Немножко» удивляет. Решил внести свои 5 копеек, поработаем с http-сервисом.

1 стартмани

15.07.2018    42194    17    dsdred    22       

Готовые переносы данных из различных конфигураций 1C Промо

Рекомендуем готовые решения для переноса данных из различных конфигураций 1C. C техподдержкой от разработчиков и гарантией от Инфостарт.

ВСТАВИТЬ В Справочник.Номенклатура (Код, Наименование) ЗНАЧЕНИЯ ("001", "Новый товар") 105

Инструменты и обработки Программист Внешняя обработка (ert,epf) v8 v8::Запросы 1cv8.cf Абонемент ($m) Практика программирования

Вас не обманывают ваши глаза, это запрос на изменение данных! И это работает без прямого доступа к БД, регистрации и смс.

1 стартмани

01.06.2018    20801    86    m-rv    57       

Вакансия Программист, аналитик, эксперт 1С Промо

Приглашаем к сотрудничеству квалифицированных специалистов 1С из любых регионов, готовых работать в удаленном режиме, а также с возможностью при необходимости выезда к заказчику.

БСП: Дополнительная обработка (Регламенты) + Расширения, примеры от сложного к универсальному 72

Статья Программист Архив с данными v8 v8::УФ 1cv8.cf Абонемент ($m) Практика программирования БСП (Библиотека стандартных подсистем)

Продолжение статьи «БСП: Дополнительная обработка (Регламенты), примеры от простого к сложному». Пойдем от финального примера той статьи и сделаем несколько шагов навстречу к универсальному решению.

2 стартмани

21.05.2018    13209    12    dsdred    17       

Велостыли: Регламентные задания 17

Статья Программист Нет файла Россия Бесплатно (free) Практика программирования

Переделывая очередное «Костыльное» решение, в голову пришла мысль, собрать все странные решения в одну статью, чтобы была некая библиотека о том, как делать не надо (Навеяно вредными советами). Потом понял, что в одну статью не получится все записать, начну с регламентных заданий. Поясню, в данную статью попали примеры из жизни, которые так или иначе реализованы на механизме регламентных заданий, при этом совершенно не всегда этот подход в принципе оправдан.

09.05.2018    10935    dsdred    28       

Вакансия Автор новостных обзоров на тему 1С и бухучета, По совместительству Промо

Редакция Infostart.ru будет рада сотрудничеству с 1С-специалистом, умеющим и любящим излагать свои мысли в письменной форме. Если вы работали в IT-изданиях или имеете опыт ведения технологического блога/канала/группы, если сможете сделать обзор обработок из каталога infostart.ru/public/all/, то у вас большое преимущество.

Как выполнить отчет на СКД через COM и получить данные отчета? 86

Статья Программист Архив с данными v8 УПП1 Россия Windows Абонемент ($m) Практика программирования

Для чего это нужно. Например, нужно в одной базе получить какой-либо показатель из другой базы. Этот показатель вычисляется в каком-либо сложном отчете, который написан на СКД. Можно, конечно, "скопипастить" текст запроса из другой базы, немного подправить его и выполнять в том же COM подключении. Но с этим теряется гибкость: если отчет изменился, то нужно помнить о том, что где-то есть его "немного модифицированная" копия. В статье будет рассмотрен пример получения данных из базы ЗУП.

2 стартмани

08.05.2018    18903    10    wowik    3       

Работа со схемой запроса 176

Статья Программист Конфигурация (md, cf) v8 v8::Запросы Абонемент ($m) Инструментарий разработчика Практика программирования

Стандартом взаимодействия с реляционной базой данных стал язык SQL. Приемником SQL в 1С является язык запросов. Язык запросов, также как и SQL, является структурированным. Составляющие структуры запроса отвечают на разные вопросы о том, какие данные требуется получить и какие манипуляции с множествами данных необходимо произвести при получении. В простых случаях текст запроса можно написать вручную, однако в сложных случаях, а также при программном формировании, - лучше воспользоваться объектной моделью запроса и использовать объект "Схема запроса". В статье дается описание объектной модели и особенностей работы с ней, а также приводится решение, упрощающее взаимодействие с объектом "Схема запроса".

1 стартмани

24.04.2018    30023    75    kalyaka    34       

С 2020 года сервис «Продление поддержки конфигурации 1С:УПП» подорожает вдвое Промо

Успейте продлить поддержку УПП до повышения цен! Фирма «1С» предупредила об изменении цен на сервис «Продление поддержки конфигурации "1С:Управление производственным предприятием"». С 1 января 2020 года сервис подорожает в два раза.

Заполняем по шаблону (по умолчанию) 69

Инструменты и обработки Программист Архив с данными v8 v8::УФ 1cv8.cf Абонемент ($m) Практика программирования

Простой в подключении, универсальный и достаточно удобный механизм заполнения реквизитов произвольных документов/справочников значениями по умолчанию. Реализован в расширении, но может быть и непосредственно включен практически в любую конфигурацию на управляемых формах простым копированием одной формы и двух команд. Весь код в статье.

1 стартмани

08.02.2018    18654    20    mvxyz    17       

Бесплатная проверка контрагентов в ФНС (общий модуль с алгоритмом). На примере выводим статус в список справочника контрагентов 124

Статья Программист Конфигурация (md, cf) v8 1cv8.cf Абонемент ($m) Практика программирования

Если вам интересно проверить контрагенте в ФНС, вам поможет данная публикация. Весь алгоритм работы строится на основе данных, полученных с сервиса http://npchk.nalog.ru совершенно бесплатно.

1 стартмани

01.02.2018    26389    62    rpgshnik    46